From 2731b33fe2d05fe3ebc3e2f98d39eacf7295d1e4 Mon Sep 17 00:00:00 2001
From: Ralph Amissah <ralph.amissah@gmail.com>
Date: Sat, 16 Nov 2019 12:16:08 -0500
Subject: module & src renaming

---
 src/doc_reform/io_out/epub3.d | 814 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 814 insertions(+)
 create mode 100644 src/doc_reform/io_out/epub3.d

(limited to 'src/doc_reform/io_out/epub3.d')

diff --git a/src/doc_reform/io_out/epub3.d b/src/doc_reform/io_out/epub3.d
new file mode 100644
index 0000000..14038a8
--- /dev/null
+++ b/src/doc_reform/io_out/epub3.d
@@ -0,0 +1,814 @@
+module doc_reform.io_out.epub3;
+template outputEPub3() {
+  import doc_reform.io_out;
+  import
+    std.digest.sha,
+    std.file,
+    std.outbuffer,
+    std.uri,
+    std.zip,
+    std.conv : to;
+  import
+    doc_reform.io_out.create_zip_file,
+    doc_reform.io_out.xmls,
+    doc_reform.io_out.xmls_css;
+  mixin InternalMarkup;
+  mixin outputXHTMLs;
+  string epub3_mimetypes() {
+    string o;
+    o = format(q"┃application/epub+zip┃") ~ "\n";
+    return o;
+  }
+  string epub3_container_xml() {
+    string o;
+    o = format(q"┃<?xml version='1.0' encoding='utf-8'?>┃") ~ "\n";
+    o ~= format(q"┃<container version="1.0"
+  xmlns="urn:oasis:names:tc:opendocument:xmlns:container">
+  <rootfiles>
+    <rootfile full-path="OEBPS/content.opf"
+      media-type="application/oebps-package+xml" />
+  </rootfiles>┃") ~ "\n</container>\n";
+    return o;
+  }
+  string epub3_oebps_content(D,M,P)(D doc_abstraction, M doc_matters, P parts) {
+    auto xhtml_format = outputXHTMLs();
+    auto pth_epub3 = spinePathsEPUB!()(doc_matters.output_path, doc_matters.src.language);
+    string _uuid = "18275d951861c77f78acd05672c9906924c59f18a2e0ba06dad95959693e9bd8"; // TODO sort uuid in doc_matters!
+    string content = format(q"┃  <?xml version='1.0' encoding='utf-8'?>
+  <package xmlns="http://www.idpf.org/2007/opf" version="2.0" unique-identifier="EPB-UUID">
+    <metadata
+      xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
+      xmlns:dcterms="http://purl.org/dc/terms/"
+      xmlns:dc="http://purl.org/dc/elements/1.1/"
+      unique-identifier="urn:uuid:%s" version="2.0">
+      <!-- <dc:title id="title">%s</dc:title> -->
+      <dc:title id="title">%s</dc:title>
+      <meta refines="#title" property="title-type">main</meta>
+      <dc:title id="subtitle">%s</dc:title>
+      <meta refines="#subtitle" property="title-type">subtitle</meta>
+      <dc:creator file-as="%s" id="aut">%s</dc:creator>
+      <dc:language>%s</dc:language>
+      <dc:date id="published">%s</dc:date>
+      <dc:rights>Copyright: %s</dc:rights>
+      <dc:identifier scheme="URI">%s</dc:identifier>
+      <dc:identifier id="bookid">urn:uuid:%s</dc:identifier>
+      <!-- <dc:identifier id="EPB-UUID">urn:uuid:%s</dc:identifier> -->
+    </metadata>
+    <manifest>
+      <!-- NCX epub2 navigation -->
+        <item id="ncx" href="toc.ncx" media-type="application/x-dtbncx+xml" />
+      <!-- CSS Style Sheets -->
+        <link rel="stylesheet" href="%s" type="text/css" id="main-css" />
+      <!-- nav epub3 navigation -->
+        <item id="nav" href="toc_nav.xhtml" media-type="application/xhtml+xml" properties="nav" />
+  ┃",
+      _uuid,
+      xhtml_format.special_characters_text(doc_matters.conf_make_meta.meta.title_full),
+      xhtml_format.special_characters_text(doc_matters.conf_make_meta.meta.title_main),
+      (doc_matters.conf_make_meta.meta.title_sub.empty)
+        ? "" : xhtml_format.special_characters_text(doc_matters.conf_make_meta.meta.title_sub),
+      (doc_matters.conf_make_meta.meta.creator_author.empty)
+        ? "" : xhtml_format.special_characters_text(doc_matters.conf_make_meta.meta.creator_author),
+      (doc_matters.conf_make_meta.meta.creator_author.empty)
+        ? "" : xhtml_format.special_characters_text(doc_matters.conf_make_meta.meta.creator_author),
+      doc_matters.src.language,                                   // language, fix (needed in dochead metadata)
+      (doc_matters.conf_make_meta.meta.date_published.empty)
+        ? "" : xhtml_format.special_characters_text(doc_matters.conf_make_meta.meta.date_published),
+      (doc_matters.conf_make_meta.meta.rights_copyright.empty)
+        ? "" : xhtml_format.special_characters_text(doc_matters.conf_make_meta.meta.rights_copyright),
+      _uuid,
+      _uuid,
+      _uuid,
+      (pth_epub3.fn_oebps_css).chompPrefix("OEBPS/"),
+    );
+    content ~= "    " ~ "<!-- Content Documents -->" ~ "\n  ";
+    content ~= parts["manifest_documents"];
+    // TODO sort jpg & png
+    content ~= "    " ~ "<!-- Images -->" ~ "\n  ";
+    foreach (image; doc_matters.srcs.image_list) {
+      content ~= format(q"┃      <item id="%s" href="%s/%s" media-type="image/%s" />
+  ┃",
+        image.baseName.stripExtension,
+        (pth_epub3.doc_oebps_image).chompPrefix("OEBPS/"),
+        image,
+        image.extension.chompPrefix("."),
+      );
+    }
+    content ~= "  " ~ "</manifest>"         ~ "\n  ";
+    content ~= "  " ~ "<spine toc=\"ncx\">" ~ "\n  ";
+    content ~= parts["spine"];
+    content ~= "  " ~ "</spine>"            ~ "\n  ";
+    content ~= "  " ~ "<guide>"             ~ "\n  ";
+    content ~= parts["guide"];
+    content ~= "  " ~ "</guide>"            ~ "\n  ";
+    content ~= ""   ~ "</package>";
+    debug(epubmanifest) {
+      foreach (part; doc_matters.has.keys_seq.seg) { // TODO
+        foreach (obj; doc_abstraction[part]) {
+          if (obj.metainfo.is_a == "heading") {
+            if (obj.metainfo.heading_lev_markup == 4) {
+              writefln(
+                "%s~ [%s.xhtml] %s",
+                obj.marked_up_level,
+                obj.tags.segment_anchor_tag_epub,
+                obj.text
+              );
+            } else if (obj.metainfo.heading_lev_markup > 4) {
+              writefln(
+                "%s~ [%s.xhtml#%s] %s",
+                obj.marked_up_level,
+                obj.tags.segment_anchor_tag_epub,
+                obj.metainfo.object_number,
+                obj.text
+              );
+            }
+          }
+        }
+      }
+    }
+    return content;
+  }
+  string epub3_oebps_toc_nav_xhtml(D,I)(D doc_abstraction, I doc_matters) {
+    enum DomTags { none, open, close, close_and_open, open_still, }
+    auto markup = InlineMarkup();
+    auto rgx = Rgx();
+    string toc =format("<html xmlns=\"http://www.w3.org/1999/xhtml\"
+      xmlns:epub=\"http://www.idpf.org/2007/ops\">
+  <head>
+    <title>%s</title>
+  </head>
+  <body>
+    <section epub:type=\"frontmatter toc\">
+      <header>
+        <h1>Contents</h1>
+      </header>
+      <nav epub:type=\"toc\" id=\"toc\">\n",
+      doc_matters.conf_make_meta.meta.title_full,
+    );
+    foreach (sect; doc_matters.has.keys_seq.seg) {
+      foreach (obj; doc_abstraction[sect]) {
+        if (obj.metainfo.is_a == "heading") {
+          string _txt = obj.text.replaceAll(rgx.inline_notes_al_gen, "").strip;
+          foreach_reverse (n; 0 .. 7) {
+            string k = n.to!string;
+            switch (obj.metainfo.dom_structure_collapsed_tags_status[n]) {
+            case DomTags.close :
+              toc ~= markup.indent_by_spaces_provided((n + 1), "  ") ~ "</li>" ~ "\n";
+              toc ~= markup.indent_by_spaces_provided(n, "  ") ~ "</ol>" ~ "\n";
+              break;
+            case DomTags.close_and_open :
+              toc ~= markup.indent_by_spaces_provided((n + 1), "  ") ~ "</li>" ~ "\n";
+              if  (obj.metainfo.heading_lev_markup < 4) {
+                toc ~= markup.indent_by_spaces_provided((n + 1), "  ") ~ "<li>" ~ "\n"
+                ~ markup.indent_by_spaces_provided((n + 2), "  ")
+                ~ "<a href=\"" ~ obj.tags.segment_anchor_tag_epub ~ ".xhtml" ~ "\">"
+                ~ _txt
+                ~ "</a>" ~ "\n";
+              } else {
+                string hashtag =(obj.metainfo.heading_lev_markup == 4)
+                ? ""
+                : ("#" ~ obj.metainfo.ocn.to!string);
+                toc ~= markup.indent_by_spaces_provided((n + 1), "  ") ~ "<li>" ~ "\n"
+                ~ markup.indent_by_spaces_provided((n + 2), "  ")
+                ~ "<a href=\"" ~ obj.tags.segment_anchor_tag_epub ~ ".xhtml" ~ hashtag ~ "\">"
+                ~ _txt
+                ~ "</a>" ~ "\n";
+              }
+              break;
+            case DomTags.open :
+              toc ~= markup.indent_by_spaces_provided(n, "  ") ~ "<ol>" ~ "\n";
+              if  (obj.metainfo.heading_lev_markup < 4) {
+                toc ~= markup.indent_by_spaces_provided((n + 1), "  ") ~ "<li>" ~ "\n"
+                ~ markup.indent_by_spaces_provided((n + 2), "  ")
+                ~ "<a href=\"" ~ obj.tags.segment_anchor_tag_epub ~ ".xhtml" ~ "\">"
+                ~ _txt
+                ~ "</a>" ~ "\n";
+              } else {
+                string hashtag =(obj.metainfo.heading_lev_markup == 4)
+                ? ""
+                : ("#" ~ obj.metainfo.ocn.to!string);
+                toc ~= markup.indent_by_spaces_provided((n + 1), "  ") ~ "<li>" ~ "\n"
+                ~ markup.indent_by_spaces_provided((n + 2), "  ")
+                ~ "<a href=\"" ~ obj.tags.segment_anchor_tag_epub ~ ".xhtml" ~ hashtag ~ "\">"
+                ~ _txt
+                ~ "</a>" ~ "\n";
+              }
+              break;
+            default :
+              break;
+            }
+          }
+        }
+      }
+    }
+    toc ~="</nav>
+      </section>
+    </body>
+  </html>\n";
+    return toc;
+  }
+  string epub2_oebps_toc_ncx(D,I)(D doc_abstraction, I doc_matters) {
+    int counter = 0;
+    string _uuid = "18275d951861c77f78acd05672c9906924c59f18a2e0ba06dad95959693e9bd8"; // TODO shared elsewhere
+    auto markup = InlineMarkup();
+    auto rgx = Rgx();
+    enum DomTags { none, open, close, close_and_open, open_still, }
+    string toc = format(q"┃<?xml version='1.0' encoding='utf-8'?>
+  <ncx xmlns="http://www.daisy.org/z3986/2005/ncx/" version="2005-1">
+  <head>
+    <!-- four required metadata items (for all NCX documents,
+      (including the relaxed constraints of OPS 2.0) -->
+    <title>%s%s</title>
+    <link rel="stylesheet" href="css/epub.css" type="text/css" id="main-css" />
+    <meta name="dtb:uid" content="urn:uuid:%s" />
+    <!-- <meta name="epub-creator" content="spine http://www.jus.uio.no/sisu (this copy)" /> -->
+    <meta name="dtb:depth" content="%s" />
+    <meta name="dtb:totalPageCount" content="0" />
+    <meta name="dtb:maxPageNumber" content="0" />
+  </head>
+  <docTitle>
+    <text>%s</text>
+  </docTitle>
+  <docAuthor>
+    <text>%s</text>
+  </docAuthor>
+  <navMap>┃",
+      doc_matters.conf_make_meta.meta.title_full,                          // title
+      (doc_matters.conf_make_meta.meta.creator_author.empty) ? ""
+        : " by " ~ doc_matters.conf_make_meta.meta.creator_author,         // author
+      _uuid,                                                                // uuid
+      "3",                                                                 // content depth
+      doc_matters.conf_make_meta.meta.title_full,                          // title
+      (doc_matters.conf_make_meta.meta.creator_author.empty) ? ""
+        : doc_matters.conf_make_meta.meta.creator_author,                  // author
+    );
+    foreach (sect; doc_matters.has.keys_seq.seg) {
+      foreach (obj; doc_abstraction[sect]) {
+        if (obj.metainfo.is_a == "heading") {
+          string _txt = obj.text.replaceAll(rgx.inline_notes_al_gen, "").strip;
+          string hashtag =(obj.metainfo.heading_lev_markup <= 4) ? "" : ("#" ~ obj.metainfo.ocn.to!string);
+          foreach_reverse (k; 0 .. 7) {
+            switch (obj.metainfo.dom_structure_markedup_tags_status[k]) {
+            case DomTags.close :
+              toc ~= "\n    </navPoint>";
+              break;
+            case DomTags.close_and_open :
+              ++counter;
+              toc ~= "\n    </navPoint>";
+              toc ~= format(q"┃
+    <navPoint class="chapter" id="navpoint" playOrder="%s">
+      <navLabel>
+        <text>%s</text>
+      </navLabel>
+      <content src="%s.xhtml%s" />┃",
+                counter,
+                _txt,
+                obj.tags.segment_anchor_tag_epub,
+                hashtag,
+              );
+              break;
+            case DomTags.open :
+              ++counter;
+              toc ~= format(q"┃
+    <navPoint class="chapter" id="navpoint" playOrder="%s">
+      <navLabel>
+        <text>%s</text>
+      </navLabel>
+      <content src="%s.xhtml%s" />┃",
+                counter,
+                _txt,
+                obj.tags.segment_anchor_tag_epub,
+                hashtag,
+              );
+              break;
+            default :
+              break;
+            }
+          }
+        }
+      }
+    }
+    toc ~= format(q"┃
+      </navPoint>
+      </navPoint>
+      </navPoint>
+    </navMap>
+  </ncx>┃");
+    return toc;
+  }
+  
+  void outputEPub3(D,I)(
+    const D    doc_abstraction,
+          I    doc_matters,
+  ) {
+    mixin spineOutputRgxInit;
+    auto xhtml_format = outputXHTMLs();
+    auto rgx = Rgx();
+    string[] doc;
+    string segment_filename;
+    string[] top_level_headings = ["","","",""];
+    string[string] oepbs_content_parts;
+    string suffix = ".xhtml";
+    struct writeOut { /+ epub specific documents +/
+      /+ fixed output +/
+      string mimetypes;
+      string meta_inf_container_xml;
+      string oebps_toc_ncx;
+      string oebps_toc_nav_xhtml;
+      /+ variable output +/
+      string oebps_content_opf;
+      string[][string] doc_epub3;
+      string[][string] doc_epub3_endnotes;
+      string[] doc_parts;
+    }
+    auto epubWrite = writeOut();
+    foreach (part; doc_matters.has.keys_seq.seg) {
+      foreach (obj; doc_abstraction[part]) {
+        string _txt = xhtml_format.special_characters(obj);
+        if (obj.metainfo.is_a == "heading") {
+          assert(part == "head" || "toc" || "body" || "endnotes" || "glossary" || "bibliography" || "bookindex" || "blurb" || "tail");
+          switch (obj.metainfo.heading_lev_markup) {
+          case 0: .. case 3:
+            /+ fill buffer, and replace with new levels from 1 to 3 +/
+            switch (obj.metainfo.heading_lev_markup) {
+            case 0:
+              top_level_headings[0] = "";
+              top_level_headings[1] = "";
+              top_level_headings[2] = "";
+              top_level_headings[3] = "";
+              goto default;
+            case 1:
+              top_level_headings[1] = "";
+              top_level_headings[2] = "";
+              top_level_headings[3] = "";
+              goto default;
+            case 2:
+              top_level_headings[2] = "";
+              top_level_headings[3] = "";
+              goto default;
+            case 3:
+              top_level_headings[3] = "";
+              goto default;
+            default:
+              epubWrite.doc_parts ~= obj.tags.segment_anchor_tag_epub;
+              epubWrite.doc_epub3[obj.tags.segment_anchor_tag_epub] ~= xhtml_format.epub3_seg_head(doc_matters);
+              auto t = xhtml_format.heading_seg(_txt, obj, doc_matters, suffix, "epub");
+              epubWrite.doc_epub3[obj.tags.segment_anchor_tag_epub] ~= t[0];
+              epubWrite.doc_epub3_endnotes[obj.tags.segment_anchor_tag_epub] ~= t[1];
+              break;
+            }
+            break;
+          case 4:
+            segment_filename = obj.tags.segment_anchor_tag_epub;
+            epubWrite.doc_epub3[segment_filename] ~= xhtml_format.epub3_seg_head(doc_matters);
+            auto t = xhtml_format.heading_seg(_txt, obj, doc_matters, suffix, "epub");
+            epubWrite.doc_epub3[segment_filename] ~= t[0];
+            epubWrite.doc_epub3_endnotes[segment_filename] ~= t[1];
+            break;
+          case 5: .. case 7:
+            auto t = xhtml_format.heading_seg(_txt, obj, doc_matters, suffix, "epub");
+            epubWrite.doc_epub3[segment_filename] ~= t[0];
+            epubWrite.doc_epub3_endnotes[segment_filename] ~= t[1];
+            break;
+          case 8: .. case 9:
+            { /+ debug +/
+              if (doc_matters.opt.action.debug_do
+              && doc_matters.opt.action.verbose) {
+                writeln(__FILE__, ":", __LINE__, ": ", obj.metainfo.is_a, ": ", obj.metainfo.heading_lev_markup);
+                writeln(__FILE__, ":", __LINE__, ": ", obj.text);
+              }
+            }
+            break;
+          default:
+            { /+ debug +/
+              if (doc_matters.opt.action.debug_do
+              && doc_matters.opt.action.verbose) {
+                writeln(__FILE__, ":", __LINE__, ": ", obj.metainfo.is_a, ": ", obj.metainfo.heading_lev_markup);
+              }
+            }
+            break;
+          }
+        } else {
+          assert(part == "head" || "toc" || "body" || "endnotes" || "glossary" || "bibliography" || "bookindex" || "blurb" || "tail");
+          switch (obj.metainfo.is_of_part) {
+          case "frontmatter":             assert(part == "head" || "toc");
+            switch (obj.metainfo.is_of_type) {
+            case "para":
+              switch (obj.metainfo.is_a) {
+              case "toc":
+                auto t = xhtml_format.para_seg(_txt, obj, doc_matters, suffix, "epub");
+                epubWrite.doc_epub3[segment_filename] ~= t[0];
+                epubWrite.doc_epub3_endnotes[segment_filename] ~= t[1];
+                break;
+              default:
+                { /+ debug +/
+                  if (doc_matters.opt.action.debug_do
+                  && doc_matters.opt.action.verbose) {
+                    writeln(__FILE__, ":", __LINE__, ": ", obj.metainfo.is_a);
+                  }
+                }
+                break;
+              }
+              break;
+            default:
+              { /+ debug +/
+                if (doc_matters.opt.action.debug_do
+                && doc_matters.opt.action.verbose) {
+                  writeln(__FILE__, ":", __LINE__, ": ", obj.metainfo.is_of_type);
+                }
+              }
+              break;
+            }
+            break;
+          case "body":                    assert(part == "body");
+            switch (obj.metainfo.is_of_type) {
+            case "para":
+              switch (obj.metainfo.is_a) {
+              case "para":
+                auto t = xhtml_format.para_seg(_txt, obj, doc_matters, suffix, "epub");
+                epubWrite.doc_epub3[segment_filename] ~= t[0];
+                epubWrite.doc_epub3_endnotes[segment_filename] ~= t[1];
+                break;
+              default:
+                { /+ debug +/
+                  if (doc_matters.opt.action.debug_do
+                  && doc_matters.opt.action.verbose) {
+                    writeln(__FILE__, ":", __LINE__, ": ", obj.metainfo.is_a);
+                  }
+                }
+                break;
+              }
+              break;
+            case "block":
+              switch (obj.metainfo.is_a) {
+              case "quote":
+                auto t = xhtml_format.quote_seg(_txt, obj, doc_matters, suffix, "epub");
+                epubWrite.doc_epub3[segment_filename] ~= t[0].to!string;
+                epubWrite.doc_epub3_endnotes[segment_filename] ~= t[1];
+                break;
+              case "group":
+                auto t = xhtml_format.group_seg(_txt, obj, doc_matters, suffix, "epub");
+                epubWrite.doc_epub3[segment_filename] ~= t[0].to!string;
+                epubWrite.doc_epub3_endnotes[segment_filename] ~= t[1];
+                break;
+              case "block":
+                auto t = xhtml_format.block_seg(_txt, obj, doc_matters, suffix, "epub");
+                epubWrite.doc_epub3[segment_filename] ~= t[0].to!string;
+                epubWrite.doc_epub3_endnotes[segment_filename] ~= t[1];
+                break;
+              case "poem":
+                break;
+              case "verse":
+                auto t = xhtml_format.verse_seg(_txt, obj, doc_matters, suffix, "epub");
+                epubWrite.doc_epub3[segment_filename] ~= t[0].to!string;
+                epubWrite.doc_epub3_endnotes[segment_filename] ~= t[1];
+                break;
+              case "code":
+                epubWrite.doc_epub3[segment_filename] ~= xhtml_format.code(_txt, obj, doc_matters);
+                break;
+              case "table":
+                epubWrite.doc_epub3[segment_filename] ~= xhtml_format.table(_txt, obj, doc_matters);
+                epubWrite.doc_epub3_endnotes[segment_filename] ~= "";
+                break;
+              default:
+                { /+ debug +/
+                  if (doc_matters.opt.action.debug_do
+                  && doc_matters.opt.action.verbose) {
+                    writeln(__FILE__, ":", __LINE__, ": ", obj.metainfo.is_a);
+                  }
+                }
+                break;
+              }
+              break;
+            default:
+              { /+ debug +/
+                if (doc_matters.opt.action.debug_do
+                && doc_matters.opt.action.verbose) {
+                  writeln(__FILE__, ":", __LINE__, ": ", obj.metainfo.is_of_type);
+                }
+              }
+              break;
+            }
+            break;
+          case "backmatter":
+            assert(part == "endnotes" || "glossary" || "bibliography" || "bookindex" || "blurb" || "tail");
+            switch (obj.metainfo.is_of_type) {
+            case "para":
+              switch (obj.metainfo.is_a) {
+              case "endnote":             assert(part == "endnotes");
+                auto t = xhtml_format.para_seg(_txt, obj, doc_matters, suffix, "epub");
+                epubWrite.doc_epub3[segment_filename] ~= t[0];
+                break;
+              case "glossary":            assert(part == "glossary");
+                auto t = xhtml_format.para_seg(_txt, obj, doc_matters, suffix, "epub");
+                epubWrite.doc_epub3[segment_filename] ~= t[0];
+                epubWrite.doc_epub3_endnotes[segment_filename] ~= t[1];
+                break;
+              case "bibliography":        assert(part == "bibliography");
+                auto t = xhtml_format.para_seg(_txt, obj, doc_matters, suffix, "epub");
+                epubWrite.doc_epub3[segment_filename] ~= t[0];
+                epubWrite.doc_epub3_endnotes[segment_filename] ~= t[1];
+                break;
+              case "bookindex":           assert(part == "bookindex");
+                auto t = xhtml_format.para_seg(_txt, obj, doc_matters, suffix, "epub");
+                epubWrite.doc_epub3[segment_filename] ~= t[0];
+                epubWrite.doc_epub3_endnotes[segment_filename] ~= t[1];
+                break;
+              case "blurb":               assert(part == "blurb");
+                auto t = xhtml_format.para_seg(_txt, obj, doc_matters, suffix, "epub");
+                epubWrite.doc_epub3[segment_filename] ~= t[0];
+                epubWrite.doc_epub3_endnotes[segment_filename] ~= t[1];
+                break;
+              default:
+                { /+ debug +/
+                  if (doc_matters.opt.action.debug_do
+                  && doc_matters.opt.action.verbose) {
+                    writeln(__FILE__, ":", __LINE__, ": ", obj.metainfo.is_a);
+                  }
+                }
+                break;
+              }
+              break;
+            default:
+              { /+ debug +/
+                if (doc_matters.opt.action.debug_do
+                && doc_matters.opt.action.verbose) {
+                  writeln(__FILE__, ":", __LINE__, ": ", obj.metainfo.is_of_type);
+                }
+              }
+              break;
+            }
+            break;
+          case "comment":
+            break;
+          default:
+            { /+ debug +/
+              if (doc_matters.opt.action.debug_do
+              && doc_matters.opt.action.verbose) {
+                writeln(__FILE__, ":", __LINE__, ": ", obj.metainfo.is_of_part);
+              }
+            }
+            break;
+          }
+        }
+        if (obj.metainfo.is_a == "heading") {
+          assert(obj.text.length > 0);
+          if (obj.metainfo.heading_lev_markup <= 4) {
+            oepbs_content_parts["manifest_documents"] ~=
+              format(q"┃      <item id="%s.xhtml" href="%s.xhtml" media-type="application/xhtml+xml" />
+  ┃",
+              obj.tags.segment_anchor_tag_epub,
+              obj.tags.segment_anchor_tag_epub,
+            );
+            oepbs_content_parts["spine"] ~=
+              format(q"┃    <itemref idref="%s.xhtml" linear="yes" />
+  ┃",
+              obj.tags.segment_anchor_tag_epub,
+            );
+            oepbs_content_parts["guide"] ~=
+              format(q"┃      <reference type="%s" href="%s" />
+  ┃",
+              obj.tags.segment_anchor_tag_epub,
+              obj.tags.segment_anchor_tag_epub,
+            );
+          } else if (obj.metainfo.heading_lev_markup > 4) {
+            oepbs_content_parts["manifest_documents"] ~=
+              format(q"┃      <item id="%s.xhtml#%s" href="%s.xhtml#%s" media-type="application/xhtml+xml" />
+  ┃",
+              obj.tags.segment_anchor_tag_epub,
+              obj.metainfo.object_number,
+              obj.tags.segment_anchor_tag_epub,
+              obj.metainfo.object_number,
+            );
+            oepbs_content_parts["spine"] ~=
+              format(q"┃    <itemref idref="%s.xhtml#%s" linear="yes" />
+  ┃",
+              obj.tags.segment_anchor_tag_epub,
+              obj.metainfo.object_number,
+            );
+            oepbs_content_parts["guide"] ~=
+              format(q"┃      <reference type="%s#%s" href="%s#%s" />
+  ┃",
+              obj.tags.segment_anchor_tag_epub,
+              obj.metainfo.object_number,
+              obj.tags.segment_anchor_tag_epub,
+              obj.metainfo.object_number,
+            );
+          }
+        }
+      }
+    }
+    /+ epub specific documents +/
+    epubWrite.mimetypes =              epub3_mimetypes;
+    epubWrite.meta_inf_container_xml = epub3_container_xml;
+    epubWrite.oebps_toc_ncx =          doc_abstraction.epub2_oebps_toc_ncx(doc_matters);
+    epubWrite.oebps_toc_nav_xhtml =    doc_abstraction.epub3_oebps_toc_nav_xhtml(doc_matters);
+    epubWrite.oebps_content_opf =      doc_abstraction.epub3_oebps_content(doc_matters, oepbs_content_parts);
+    epubWrite.epub3_write_output_files(doc_matters);
+  }
+  void epub3_write_output_files(W,M)(
+    W epub_write,
+    M doc_matters,
+  ) {
+    debug(asserts) {
+      static assert(is(typeof(epub_write.doc_epub3)              == string[][string]));
+      static assert(is(typeof(epub_write.mimetypes)              == string));
+      static assert(is(typeof(epub_write.meta_inf_container_xml) == string));
+      static assert(is(typeof(epub_write.oebps_toc_nav_xhtml)    == string));
+      static assert(is(typeof(epub_write.oebps_toc_ncx)          == string));
+      static assert(is(typeof(epub_write.oebps_content_opf)      == string));
+    }
+    static auto rgx = Rgx();
+    auto pth_epub3 = spinePathsEPUB!()(doc_matters.output_path, doc_matters.src.language);
+    auto xhtml_format = outputXHTMLs();
+    /+ zip file +/
+    auto fn_epub = pth_epub3.epub_file(doc_matters.src.filename);
+    auto zip = new ZipArchive(); // ZipArchive zip = new ZipArchive();
+    /+ zip archive member files +/
+    void EPUBzip()(string contents, string fn) {
+      auto zip_arc_member_file = new ArchiveMember();
+      zip_arc_member_file.name = fn;
+      auto zip_data = new OutBuffer();
+      (doc_matters.opt.action.debug_do)
+      ? zip_data.write(contents.dup)
+      : zip_data.write(contents.dup
+        .replaceAll(rgx.spaces_line_start, "")
+        .replaceAll(rgx.newline, " ")
+        .strip
+      );
+      zip_arc_member_file.expandedData = zip_data.toBytes();
+      zip.addMember(zip_arc_member_file);
+      createZipFile!()(fn_epub, zip.build());
+    }
+    try {
+      if (!exists(pth_epub3.base)) {
+        pth_epub3.base.mkdirRecurse;
+      }
+      { /+ debug +/
+        if (doc_matters.opt.action.debug_do) {
+          if (!exists(pth_epub3.dbg_doc_meta_inf(doc_matters.src.filename))) {
+            pth_epub3.dbg_doc_meta_inf(doc_matters.src.filename).mkdirRecurse;
+          }
+          if (!exists(pth_epub3.dbg_doc_oebps_css(doc_matters.src.filename))) {
+            pth_epub3.dbg_doc_oebps_css(doc_matters.src.filename).mkdirRecurse;
+          }
+          if (!exists(pth_epub3.dbg_doc_oebps_image(doc_matters.src.filename))) {
+            pth_epub3.dbg_doc_oebps_image(doc_matters.src.filename).mkdirRecurse;
+          }
+        }
+      }
+      { /+ OEBPS/[segments].xhtml (the document contents) +/
+        foreach (seg_filename; doc_matters.has.segnames_lv_0_to_4) {
+          string fn = pth_epub3.fn_oebps_content_xhtml(seg_filename);
+          auto zip_arc_member_file = new ArchiveMember();
+          zip_arc_member_file.name = fn;
+          auto zip_data = new OutBuffer();
+          { /+ debug +/
+            if (doc_matters.opt.action.debug_do) {
+              string fn_dbg = pth_epub3.dbg_fn_oebps_content_xhtml(doc_matters.src.filename, seg_filename);
+              auto f = File(fn_dbg, "w");
+              foreach (docseg; epub_write.doc_epub3[seg_filename]) {
+                f.writeln(docseg);
+              }
+              foreach (docseg; epub_write.doc_epub3_endnotes[seg_filename]) {
+                f.writeln(docseg);
+              }
+              f.writeln(xhtml_format.tail);
+            }
+          }
+          foreach (docseg; epub_write.doc_epub3[seg_filename]) {
+            zip_data.write(docseg.dup);
+          }
+          foreach (docseg; epub_write.doc_epub3_endnotes[seg_filename]) {
+            zip_data.write(docseg.dup);
+          }
+          zip_data.write(xhtml_format.tail.dup);
+          zip_arc_member_file.expandedData = zip_data.toBytes();
+          zip.addMember(zip_arc_member_file);
+          /+ create the zip file +/
+          createZipFile!()(fn_epub, zip.build());
+        }
+      }
+      string fn;
+      string fn_dbg;
+      File f;
+      { /+ mimetypes (identify zip file type) +/
+        { /+ debug +/
+          if (doc_matters.opt.action.debug_do) {
+            fn_dbg = pth_epub3.dbg_fn_mimetypes(doc_matters.src.filename);
+            File(fn_dbg, "w").writeln(epub_write.mimetypes);
+          }
+        }
+        fn = pth_epub3.fn_mimetypes;
+        EPUBzip(epub_write.mimetypes, fn);
+      }
+      { /+  META-INF/container.xml (identify doc root) +/
+        { /+ debug +/
+          if (doc_matters.opt.action.debug_do) {
+            fn_dbg = pth_epub3.dbg_fn_dmi_container_xml(doc_matters.src.filename);
+            File(fn_dbg, "w").writeln(epub_write.meta_inf_container_xml);
+          }
+        }
+        fn = pth_epub3.fn_dmi_container_xml;
+        EPUBzip(epub_write.meta_inf_container_xml, fn);
+      }
+      { /+ OEBPS/toc_nav.xhtml (navigation toc epub3) +/
+        { /+ debug +/
+          if (doc_matters.opt.action.debug_do) {
+            fn_dbg = pth_epub3.dbg_fn_oebps_toc_nav_xhtml(doc_matters.src.filename);
+            File(fn_dbg, "w").writeln(epub_write.oebps_toc_nav_xhtml);
+          }
+        }
+        fn = pth_epub3.fn_oebps_toc_nav_xhtml;
+        EPUBzip(epub_write.oebps_toc_nav_xhtml, fn);
+      }
+      { /+ OEBPS/toc.ncx (navigation toc epub2) +/
+        { /+ debug +/
+          if (doc_matters.opt.action.debug_do) {
+            fn_dbg = pth_epub3.dbg_fn_oebps_toc_ncx(doc_matters.src.filename);
+            File(fn_dbg, "w").writeln(epub_write.oebps_toc_ncx);
+          }
+        }
+        fn = pth_epub3.fn_oebps_toc_ncx;
+        EPUBzip(epub_write.oebps_toc_ncx, fn);
+      }
+      { /+ OEBPS/content.opf (doc manifest) +/
+        { /+ debug +/
+          if (doc_matters.opt.action.debug_do) {
+            fn_dbg = pth_epub3.dbg_fn_oebps_content_opf(doc_matters.src.filename);
+            File(fn_dbg, "w").writeln(epub_write.oebps_content_opf);
+          }
+        }
+        fn = pth_epub3.fn_oebps_content_opf;
+        EPUBzip(epub_write.oebps_content_opf, fn);
+      }
+      { /+ OEBPS/_dr/image (images) +/
+        foreach (image; doc_matters.srcs.image_list) {
+          { /+ debug +/
+            if (doc_matters.opt.action.debug_do) {
+              if (doc_matters.opt.action.very_verbose) {
+                writeln(
+                  doc_matters.src.image_dir_path, "/", image, " -> ",
+                  pth_epub3.dbg_doc_oebps_image(doc_matters.src.filename), "/", image
+                );
+              }
+              if (exists(doc_matters.src.image_dir_path ~ "/" ~ image)) {
+                (doc_matters.src.image_dir_path ~ "/" ~ image)
+                .copy((pth_epub3.dbg_doc_oebps_image(doc_matters.src.filename)) ~ "/" ~ image);
+              }
+            }
+          }
+          auto fn_src = doc_matters.src.image_dir_path ~ "/" ~ image;
+          auto fn_out =  pth_epub3.doc_oebps_image ~ "/" ~ image;
+          if (exists(fn_src)) {
+            {
+              auto zip_arc_member_file = new ArchiveMember();
+              zip_arc_member_file.name = fn_out;
+              auto zip_data = new OutBuffer();
+              zip_data.write(cast(char[]) ((fn_src).read));
+              zip_arc_member_file.expandedData = zip_data.toBytes();
+              zip.addMember(zip_arc_member_file);
+              createZipFile!()(fn_epub, zip.build());
+            }
+          }
+        }
+      }
+      { /+ OEBPS/epub.css +/
+        auto css = spineCss(doc_matters);
+        { /+ debug +/
+          if (doc_matters.opt.action.debug_do) {
+            fn_dbg = pth_epub3.dbg_fn_oebps_css(doc_matters.src.filename);
+            File(fn_dbg, "w").writeln(css.epub);
+          }
+        }
+        fn = pth_epub3.fn_oebps_css;
+        auto zip_arc_member_file = new ArchiveMember();
+        zip_arc_member_file.name = fn;
+        auto zip_data = new OutBuffer();
+        zip_data.write(css.epub.dup);
+        zip_arc_member_file.expandedData = zip_data.toBytes();
+        zip.addMember(zip_arc_member_file);
+        createZipFile!()(fn_epub, zip.build());
+      }
+    } catch (ErrnoException ex) {
+      // Handle error
+    }
+    if (!(doc_matters.opt.action.quiet)) {
+      writeln(" ", fn_epub);
+    }
+    debug(epub_archive) {
+      if (exists(fn_epub)) {
+        try {
+          auto zipped = new ZipArchive((fn_epub).read);
+          foreach (filename, member; zipped.directory) {
+            auto data = zipped.expand(member);
+            writeln(filename, " length ", data.length);
+          }
+        } catch (ZipException ex) {
+          // Handle errors
+        }
+      }
+    }
+  }
+  
+}
-- 
cgit v1.2.3