/++
  output hub<BR>
  check & generate output types requested
+/
module doc_reform.output.hub;
template outputHub() {
  import doc_reform.output,
    doc_reform.output.epub3,
    doc_reform.output.html,
    doc_reform.output.sqlite,
    doc_reform.output.xmls,
    doc_reform.output.source_pod,
    doc_reform.output.create_zip_file,
    doc_reform.output.paths_output;
  import std.parallelism;
  void outputHub(D,I)(D doc_abstraction, I doc_matters) {
    mixin DocReformOutputRgxInit;
    mixin Msg;
    auto msg = Msg!()(doc_matters);
    static auto rgx = Rgx();
    enum outTask { pod, source, sqlite, sqlite_multi, epub, html_scroll, html_seg, html_stuff }
    void Scheduled(D,I)(int sched, D doc_abstraction, I doc_matters) {
      auto msg = Msg!()(doc_matters);
      if (sched == outTask.pod) {
        msg.v("sisu source processing... ");
        DocReformPod!()(doc_matters);
        msg.vv("sisu source done");
      }
      if (sched == outTask.epub) {
        msg.v("epub3 processing... ");
        outputEPub3!()(doc_abstraction, doc_matters);
        msg.vv("epub3 done");
      }
      if (sched == outTask.html_scroll) {
        msg.v("html scroll processing... ");
        outputHTML!().scroll(doc_abstraction, doc_matters);
        msg.vv("html scroll done");
      }
      if (sched == outTask.html_seg) {
        msg.v("html seg processing... ");
        outputHTML!().seg(doc_abstraction, doc_matters);
        msg.vv("html seg done");
      }
      if (sched == outTask.html_stuff) {
        outputHTML!().css(doc_matters);
        outputHTML!().images_cp(doc_matters);
        msg.vv("html css & images done");
      }
      if (sched == outTask.sqlite) {
        msg.v("sqlite processing... ");
        SQLiteHubDiscreteBuildTablesAndPopulate!()(doc_matters, doc_abstraction);
        msg.vv("sqlite done");
      }
    }
    if (!(doc_matters.opt.action.parallelise_subprocesses)) {
      foreach(schedule; doc_matters.opt.action.output_task_scheduler) {
        Scheduled!()(schedule, doc_abstraction, doc_matters);
      }
    } else {
      foreach(schedule; parallel(doc_matters.opt.action.output_task_scheduler)) {
        Scheduled!()(schedule, doc_abstraction, doc_matters);
      }
    }
    if (doc_matters.opt.action.sqlite_update) {
      msg.v("sqlite update processing...");
      SQLiteHubBuildTablesAndPopulate!()(doc_matters, doc_abstraction);
      msg.vv("sqlite update done");
    } else if (doc_matters.opt.action.sqlite_delete) {
      msg.v("sqlite delete processing...");
      SQLiteHubBuildTablesAndPopulate!()(doc_matters, doc_abstraction);
      msg.vv("sqlite delete done");
    }
  }
}
template outputHubOp() {
  import doc_reform.output,
    doc_reform.output.epub3,
    doc_reform.output.html,
    doc_reform.output.sqlite,
    doc_reform.output.xmls,
    doc_reform.output.source_pod,
    doc_reform.output.create_zip_file,
    doc_reform.output.paths_output;
  void outputHubOp(E,O)(E env, O opt_action) {
    mixin DocReformOutputRgxInit;
    static auto rgx = Rgx();
    if ((opt_action.sqlite_db_drop)) {
      if ((opt_action.verbose)) {
        writeln("sqlite drop db...");
      }
      SQLiteDbDrop!()(opt_action);
      if ((opt_action.very_verbose)) {
        writeln("sqlite drop db done");
      }
    }
    if ((opt_action.sqlite_db_create)) {
      if ((opt_action.verbose)) {
        writeln("sqlite create table...");
      }
      SQLiteTablesCreate!()(env, opt_action);
      if ((opt_action.very_verbose)) {
        writeln("sqlite create table done");
      }
    }
  }
}