module sdp.output.epub3;
template outputEPub3() {
  import sdp.output;
  import
    std.digest.sha,
    std.file,
    std.outbuffer,
    std.zip,
    std.conv : to;
  import
    sdp.output.create_zip_file,
    sdp.output.xmls,
    sdp.output.xmls_css;
  mixin InternalMarkup;
  mixin outputXHTMLs;
  string epub3_mimetypes() {
    string o;
    o = format(q"¶application/epub+zip¶") ~ "\n";
    return o;
  }
  string epub3_container_xml() {
    string o;
    o = format(q"¶<?xml version='1.0' encoding='utf-8'?>¶") ~ "\n";
    o ~= format(q"¶<container version="1.0"
  xmlns="urn:oasis:names:tc:opendocument:xmlns:container">
  <rootfiles>
    <rootfile full-path="OEBPS/content.opf"
      media-type="application/oebps-package+xml" />
  </rootfiles>¶") ~ "\n</container>\n";
    return o;
  }
  string epub3_oebps_content(D,I,P)(D doc_abstraction, I doc_matters, P parts) {
    auto xhtml_format = outputXHTMLs();
    auto pth_epub3 = SiSUpathsEPUB!()(doc_matters.src_path_info, doc_matters.language);
    string uuid = "18275d951861c77f78acd05672c9906924c59f18a2e0ba06dad95959693e9bd8"; // TODO sort uuid in doc_matters!
    string content = format(q"¶  <?xml version='1.0' encoding='utf-8'?>
  <package xmlns="http://www.idpf.org/2007/opf" version="2.0" unique-identifier="EPB-UUID">
    <metadata
      xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
      xmlns:dcterms="http://purl.org/dc/terms/"
      xmlns:dc="http://purl.org/dc/elements/1.1/"
      unique-identifier="urn:uuid:%s" version="2.0">
      <!-- <dc:title id="title">%s</dc:title> -->
      <dc:title id="title">%s</dc:title>
      <meta refines="#title" property="title-type">main</meta>
      <dc:title id="subtitle">%s</dc:title>
      <meta refines="#subtitle" property="title-type">subtitle</meta>
      <dc:creator file-as="%s" id="aut">%s</dc:creator>
      <dc:language>%s</dc:language>
      <dc:date id="published">%s</dc:date>
      <dc:rights>Copyright: %s</dc:rights>
      <dc:identifier scheme="URI">%s</dc:identifier>
      <dc:identifier id="bookid">urn:uuid:%s</dc:identifier>
      <!-- <dc:identifier id="EPB-UUID">urn:uuid:%s</dc:identifier> -->
    </metadata>
    <manifest>
      <!-- NCX epub2 navigation -->
        <item id="ncx" href="toc.ncx" media-type="application/x-dtbncx+xml" />
      <!-- CSS Style Sheets -->
        <link rel="stylesheet" href="%s" type="text/css" id="main-css" />
      <!-- nav epub3 navigation -->
        <item id="nav" href="toc_nav.xhtml" media-type="application/xhtml+xml" properties="nav" />
  ¶",
      uuid,
      xhtml_format.special_characters_text(doc_matters.dochead_meta["title"]["full"]),
      xhtml_format.special_characters_text(doc_matters.dochead_meta["title"]["main"]),
      (doc_matters.dochead_meta["title"]["sub"].empty)
        ? "" : xhtml_format.special_characters_text(doc_matters.dochead_meta["title"]["sub"]),
      (doc_matters.dochead_meta["creator"]["author"].empty)
        ? "" : xhtml_format.special_characters_text(doc_matters.dochead_meta["creator"]["author"]),
      (doc_matters.dochead_meta["creator"]["author"].empty)
        ? "" : xhtml_format.special_characters_text(doc_matters.dochead_meta["creator"]["author"]),
      doc_matters.language,
      (doc_matters.dochead_meta["date"]["published"].empty)
        ? "" : xhtml_format.special_characters_text(doc_matters.dochead_meta["date"]["published"]),
      (doc_matters.dochead_meta["rights"]["copyright"].empty)
        ? "" : xhtml_format.special_characters_text(doc_matters.dochead_meta["rights"]["copyright"]),
      uuid,
      uuid,
      uuid,
      (pth_epub3.fn_oebps_css(doc_matters.source_filename)).chompPrefix("OEBPS/"),
    );
    content ~= "    " ~ "<!-- Content Documents -->" ~ "\n  ";
    content ~= parts["manifest_documents"];
    // TODO sort jpg & png
    content ~= "    " ~ "<!-- Images -->" ~ "\n  ";
    foreach (image; doc_matters.image_list) {
      content ~= format(q"¶      <item id="%s" href="%s/%s" media-type="image/%s" />
  ¶",
        image.baseName.stripExtension,
        (pth_epub3.doc_oebps_image(doc_matters.source_filename)).chompPrefix("OEBPS/"),
        image,
        image.extension.chompPrefix("."),
      );
    }
    content ~= "  " ~ "</manifest>"         ~ "\n  ";
    content ~= "  " ~ "<spine toc=\"ncx\">" ~ "\n  ";
    content ~= parts["spine"];
    content ~= "  " ~ "</spine>"            ~ "\n  ";
    content ~= "  " ~ "<guide>"             ~ "\n  ";
    content ~= parts["guide"];
    content ~= "  " ~ "</guide>"            ~ "\n  ";
    content ~= ""   ~ "</package>";
    debug(epubmanifest) {
      foreach (s; doc_matters.keys_seq.seg) {
        foreach (obj; doc_abstraction[s]) {
          if (obj.is_a == "heading") {
            if (obj.heading_lev_markup == 4) {
              writefln(
                "%s~ [%s.xhtml] %s",
                obj.marked_up_level,
                obj.segment_anchor_tag,
                obj.text
              );
            } else if (obj.heading_lev_markup > 4) {
              writefln(
                "%s~ [%s.xhtml#%s] %s",
                obj.marked_up_level,
                obj.segment_anchor_tag,
                obj.obj_cite_number,
                obj.text
              );
            }
          }
        }
      }
    }
    return content;
  }
  string epub3_oebps_toc_nav_xhtml(D,I)(D doc_abstraction, I doc_matters) {
    enum DomTags { none, open, close, close_and_open, open_still, }
    auto markup = InlineMarkup();
    auto rgx = Rgx();
    string toc =format("<html xmlns=\"http://www.w3.org/1999/xhtml\"
      xmlns:epub=\"http://www.idpf.org/2007/ops\">
  <head>
    <title>%s</title>
  </head>
  <body>
    <section epub:type=\"frontmatter toc\">
      <header>
        <h1>Contents</h1>
      </header>
      <nav epub:type=\"toc\" id=\"toc\">\n",
      doc_matters.dochead_meta["title"]["full"],
    );
    foreach (sect; doc_matters.keys_seq.seg) {
      foreach (obj; doc_abstraction[sect]) {
        if (obj.is_a == "heading") {
          string _txt = obj.text.replaceAll(rgx.inline_notes_al_gen, "").strip;
          foreach_reverse (n; 0 .. 7) {
            string k = n.to!string;
            switch (obj.dom_collapsed[n]) {
            case DomTags.close :
              toc ~= markup.indent_by_spaces_provided((n + 1), "  ") ~ "</li>" ~ "\n";
              toc ~= markup.indent_by_spaces_provided(n, "  ") ~ "</ol>" ~ "\n";
              break;
            case DomTags.close_and_open :
              toc ~= markup.indent_by_spaces_provided((n + 1), "  ") ~ "</li>" ~ "\n";
              if  (obj.heading_lev_markup < 4) {
                toc ~= markup.indent_by_spaces_provided((n + 1), "  ") ~ "<li>" ~ "\n"
                ~ markup.indent_by_spaces_provided((n + 2), "  ")
                ~ "<a href=\"" ~ obj.segment_anchor_tag ~ ".xhtml" ~ "\">"
                ~ _txt
                ~ "</a>" ~ "\n";
              } else {
                string hashtag =(obj.heading_lev_markup == 4)
                ? ""
                : ("#" ~ obj.ocn.to!string);
                toc ~= markup.indent_by_spaces_provided((n + 1), "  ") ~ "<li>" ~ "\n"
                ~ markup.indent_by_spaces_provided((n + 2), "  ")
                ~ "<a href=\"" ~ obj.segment_anchor_tag ~ ".xhtml" ~ hashtag ~ "\">"
                ~ _txt
                ~ "</a>" ~ "\n";
              }
              break;
            case DomTags.open :
              toc ~= markup.indent_by_spaces_provided(n, "  ") ~ "<ol>" ~ "\n";
              if  (obj.heading_lev_markup < 4) {
                toc ~= markup.indent_by_spaces_provided((n + 1), "  ") ~ "<li>" ~ "\n"
                ~ markup.indent_by_spaces_provided((n + 2), "  ")
                ~ "<a href=\"" ~ obj.segment_anchor_tag ~ ".xhtml" ~ "\">"
                ~ _txt
                ~ "</a>" ~ "\n";
              } else {
                string hashtag =(obj.heading_lev_markup == 4)
                ? ""
                : ("#" ~ obj.ocn.to!string);
                toc ~= markup.indent_by_spaces_provided((n + 1), "  ") ~ "<li>" ~ "\n"
                ~ markup.indent_by_spaces_provided((n + 2), "  ")
                ~ "<a href=\"" ~ obj.segment_anchor_tag ~ ".xhtml" ~ hashtag ~ "\">"
                ~ _txt
                ~ "</a>" ~ "\n";
              }
              break;
            default :
              break;
            }
          }
        }
      }
    }
    toc ~="</nav>
      </section>
    </body>
  </html>\n";
    return toc;
  }
  string epub2_oebps_toc_ncx(D,I)(D doc_abstraction, I doc_matters) {
    int counter = 0;
    string uuid = "18275d951861c77f78acd05672c9906924c59f18a2e0ba06dad95959693e9bd8"; // TODO shared elsewhere
    auto markup = InlineMarkup();
    auto rgx = Rgx();
    enum DomTags { none, open, close, close_and_open, open_still, }
    string toc = format(q"¶<?xml version='1.0' encoding='utf-8'?>
  <ncx xmlns="http://www.daisy.org/z3986/2005/ncx/" version="2005-1">
  <head>
    <!-- four required metadata items (for all NCX documents,
      (including the relaxed constraints of OPS 2.0) -->
    <title>%s%s</title>
    <link rel="stylesheet" href="css/epub.css" type="text/css" id="main-css" />
    <meta name="dtb:uid" content="urn:uuid:%s" />
    <!-- <meta name="epub-creator" content="SiSU http://www.jus.uio.no/sisu (this copy)" /> -->
    <meta name="dtb:depth" content="%s" />
    <meta name="dtb:totalPageCount" content="0" />
    <meta name="dtb:maxPageNumber" content="0" />
  </head>
  <docTitle>
    <text>%s</text>
  </docTitle>
  <docAuthor>
    <text>%s</text>
  </docAuthor>
  <navMap>¶",
      doc_matters.dochead_meta["title"]["full"],                          // title
      (doc_matters.dochead_meta["creator"]["author"].empty) ? ""
        : " by " ~ doc_matters.dochead_meta["creator"]["author"],         // author
      uuid,                                                               // uuid
      "3",                                                                // content depth
      doc_matters.dochead_meta["title"]["full"],                          // title
      (doc_matters.dochead_meta["creator"]["author"].empty) ? ""
        : doc_matters.dochead_meta["creator"]["author"],                  // author
    );
    foreach (sect; doc_matters.keys_seq.seg) {
      foreach (obj; doc_abstraction[sect]) {
        if (obj.is_a == "heading") {
          string _txt = obj.text.replaceAll(rgx.inline_notes_al_gen, "").strip;
          string hashtag =(obj.heading_lev_markup <= 4) ? "" : ("#" ~ obj.ocn.to!string);
          foreach_reverse (k; 0 .. 7) {
            switch (obj.dom_markedup[k]) {
            case DomTags.close :
              toc ~= "\n    </navPoint>";
              break;
            case DomTags.close_and_open :
              ++counter;
              toc ~= "\n    </navPoint>";
              toc ~= format(q"¶
    <navPoint class="chapter" id="navpoint" playOrder="%s">
      <navLabel>
        <text>%s</text>
      </navLabel>
      <content src="%s.xhtml%s" />¶",
                counter,
                _txt,
                obj.segment_anchor_tag,
                hashtag,
              );
              break;
            case DomTags.open :
              ++counter;
              toc ~= format(q"¶
    <navPoint class="chapter" id="navpoint" playOrder="%s">
      <navLabel>
        <text>%s</text>
      </navLabel>
      <content src="%s.xhtml%s" />¶",
                counter,
                _txt,
                obj.segment_anchor_tag,
                hashtag,
              );
              break;
            default :
              break;
            }
          }
        }
      }
    }
    toc ~= format(q"¶  </navMap>
  </ncx>¶");
    return toc;
  }
  
  void outputEPub3(D,I)(
    auto return ref const D    doc_abstraction,
    auto return ref I          doc_matters,
  ) {
    mixin SiSUoutputRgxInit;
    auto xhtml_format = outputXHTMLs();
    auto rgx = Rgx();
    string[][string] doc_epub3;
    string[][string] doc_epub3_endnotes;
    string[] doc;
    string segment_filename;
    string[] top_level_headings = ["","","",""];
    string[string] oepbs_content_parts;
    string suffix = ".xhtml";
    string[] doc_parts_;
    foreach (part; doc_matters.keys_seq.seg) {
      foreach (obj; doc_abstraction[part]) {
        string _txt = xhtml_format.special_characters(obj, obj.text);
        if (obj.is_a == "heading") {
          assert(part == "head" || "toc_seg" || "body" || "endnotes" || "glossary" || "bibliography" || "bookindex_seg" || "blurb" || "tail");
          switch (obj.heading_lev_markup) {
          case 0: .. case 3:
            /+ fill buffer, and replace with new levels from 1 to 3 +/
            switch (obj.heading_lev_markup) {
            case 0:
              top_level_headings[0] = "";
              top_level_headings[1] = "";
              top_level_headings[2] = "";
              top_level_headings[3] = "";
              goto default;
            case 1:
              top_level_headings[1] = "";
              top_level_headings[2] = "";
              top_level_headings[3] = "";
              goto default;
            case 2:
              top_level_headings[2] = "";
              top_level_headings[3] = "";
              goto default;
            case 3:
              top_level_headings[3] = "";
              goto default;
            default:
              doc_parts_ ~= obj.segment_anchor_tag;
              doc_epub3[obj.segment_anchor_tag] ~= xhtml_format.epub3_seg_head(doc_matters);
              auto t = xhtml_format.heading_seg(obj, _txt, suffix, "epub");
              doc_epub3[obj.segment_anchor_tag] ~= t[0];
              doc_epub3_endnotes[obj.segment_anchor_tag] ~= t[1];
              break;
            }
            break;
          case 4:
            segment_filename = obj.segment_anchor_tag;
            doc_epub3[segment_filename] ~= xhtml_format.epub3_seg_head(doc_matters);
            auto t = xhtml_format.heading_seg(obj, _txt, suffix, "epub");
            doc_epub3[segment_filename] ~= t[0];
            doc_epub3_endnotes[segment_filename] ~= t[1];
            break;
          case 5: .. case 7:
            auto t = xhtml_format.heading_seg(obj, _txt, suffix, "epub");
            doc_epub3[segment_filename] ~= t[0];
            doc_epub3_endnotes[segment_filename] ~= t[1];
            break;
          case 8: .. case 9:
            if ((doc_matters.opt_action_bool["debug"])) {
              writeln(__FILE__, ":", __LINE__, ": ", obj.is_a, ": ", obj.heading_lev_markup);
              writeln(__FILE__, ":", __LINE__, ": ", obj.text);
            }
            break;
          default:
            if ((doc_matters.opt_action_bool["debug"])) {
              writeln(__FILE__, ":", __LINE__, ": ", obj.is_a, ": ", obj.heading_lev_markup);
            }
            break;
          }
        } else {
          assert(part == "head" || "toc_seg" || "body" || "endnotes" || "glossary" || "bibliography" || "bookindex_seg" || "blurb" || "tail");
          switch (obj.use) {
          case "frontmatter":             assert(part == "head" || "toc_seg");
            switch (obj.is_of) {
            case "para":
              switch (obj.is_a) {
              case "toc":
                auto t = xhtml_format.para_seg(obj, _txt, suffix);
                doc_epub3[segment_filename] ~= t[0];
                doc_epub3_endnotes[segment_filename] ~= t[1];
                break;
              default:
                if ((doc_matters.opt_action_bool["debug"])) {
                  writeln(__FILE__, ":", __LINE__, ": ", obj.is_a);
                }
                break;
              }
              break;
            default:
              if ((doc_matters.opt_action_bool["debug"])) {
                writeln(__FILE__, ":", __LINE__, ": ", obj.is_of);
              }
              break;
            }
            break;
          case "body":                    assert(part == "body");
            switch (obj.is_of) {
            case "para":
              switch (obj.is_a) {
              case "para":
                auto t = xhtml_format.para_seg(obj, _txt, suffix);
                doc_epub3[segment_filename] ~= t[0];
                doc_epub3_endnotes[segment_filename] ~= t[1];
                break;
              default:
                if ((doc_matters.opt_action_bool["debug"])) {
                  writeln(__FILE__, ":", __LINE__, ": ", obj.is_a);
                }
                break;
              }
              break;
            case "block":
              switch (obj.is_a) {
              case "quote":
                auto t = xhtml_format.quote_seg(obj, _txt, suffix);
                doc_epub3[segment_filename] ~= to!string(t[0]);
                doc_epub3_endnotes[segment_filename] ~= t[1];
                break;
              case "group":
                auto t = xhtml_format.group_seg(obj, _txt, suffix);
                doc_epub3[segment_filename] ~= to!string(t[0]);
                doc_epub3_endnotes[segment_filename] ~= t[1];
                break;
              case "block":
                auto t = xhtml_format.block_seg(obj, _txt, suffix);
                doc_epub3[segment_filename] ~= to!string(t[0]);
                doc_epub3_endnotes[segment_filename] ~= t[1];
                break;
              case "poem":
                break;
              case "verse":
                auto t = xhtml_format.verse_seg(obj, _txt, suffix);
                doc_epub3[segment_filename] ~= to!string(t[0]);
                doc_epub3_endnotes[segment_filename] ~= t[1];
                break;
              case "code":
                doc_epub3[segment_filename] ~= xhtml_format.code(obj, _txt);
                break;
              case "table":
                auto t = xhtml_format.para_seg(obj, _txt, suffix);
                doc_epub3[segment_filename] ~= t[0];
                doc_epub3_endnotes[segment_filename] ~= t[1];
                break;
              default:
                if ((doc_matters.opt_action_bool["debug"])) {
                  writeln(__FILE__, ":", __LINE__, ": ", obj.is_a);
                }
                break;
              }
              break;
            default:
              if ((doc_matters.opt_action_bool["debug"])) {
                writeln(__FILE__, ":", __LINE__, ": ", obj.is_of);
              }
              break;
            }
            break;
          case "backmatter":
            assert(part == "endnotes" || "glossary" || "bibliography" || "bookindex_seg" || "blurb" || "tail");
            switch (obj.is_of) {
            case "para":
              switch (obj.is_a) {
              case "endnote":             assert(part == "endnotes");
                auto t = xhtml_format.para_seg(obj, _txt, suffix);
                doc_epub3[segment_filename] ~= t[0];
                break;
              case "glossary":            assert(part == "glossary");
                auto t = xhtml_format.para_seg(obj, _txt, suffix);
                doc_epub3[segment_filename] ~= t[0];
                doc_epub3_endnotes[segment_filename] ~= t[1];
                break;
              case "bibliography":        assert(part == "bibliography");
                auto t = xhtml_format.para_seg(obj, _txt, suffix);
                doc_epub3[segment_filename] ~= t[0];
                doc_epub3_endnotes[segment_filename] ~= t[1];
                break;
              case "bookindex":           assert(part == "bookindex_seg");
                auto t = xhtml_format.para_seg(obj, _txt, suffix);
                doc_epub3[segment_filename] ~= t[0];
                doc_epub3_endnotes[segment_filename] ~= t[1];
                break;
              case "blurb":               assert(part == "blurb");
                auto t = xhtml_format.para_seg(obj, _txt, suffix);
                doc_epub3[segment_filename] ~= t[0];
                doc_epub3_endnotes[segment_filename] ~= t[1];
                break;
              default:
                if ((doc_matters.opt_action_bool["debug"])) {
                  writeln(__FILE__, ":", __LINE__, ": ", obj.is_a);
                }
                break;
              }
              break;
            default:
              if ((doc_matters.opt_action_bool["debug"])) {
                writeln(__FILE__, ":", __LINE__, ": ", obj.is_of);
              }
              break;
            }
            break;
          case "comment":
            break;
          default:
            if ((doc_matters.opt_action_bool["debug"])) {
              writeln(__FILE__, ":", __LINE__, ": ", obj.use);
            }
            break;
          }
        }
        if (obj.is_a == "heading") {
          if (obj.heading_lev_markup <= 4) {
            oepbs_content_parts["manifest_documents"] ~=
              format(q"¶      <item id="%s.xhtml" href="%s.xhtml" media-type="application/xhtml+xml" />
  ¶",
              obj.segment_anchor_tag,
              obj.segment_anchor_tag,
            );
            oepbs_content_parts["spine"] ~=
              format(q"¶    <itemref idref="%s.xhtml" linear="yes" />
  ¶",
              obj.segment_anchor_tag,
            );
            oepbs_content_parts["guide"] ~=
              format(q"¶      <reference type="%s" href="%s" />
  ¶",
              obj.segment_anchor_tag,
              obj.segment_anchor_tag,
            );
          } else if (obj.heading_lev_markup > 4) {
            oepbs_content_parts["manifest_documents"] ~=
              format(q"¶      <item id="%s.xhtml#%s" href="%s.xhtml#%s" media-type="application/xhtml+xml" />
  ¶",
              obj.segment_anchor_tag,
              obj.obj_cite_number,
              obj.segment_anchor_tag,
              obj.obj_cite_number,
            );
            oepbs_content_parts["spine"] ~=
              format(q"¶    <itemref idref="%s.xhtml#%s" linear="yes" />
  ¶",
              obj.segment_anchor_tag,
              obj.obj_cite_number,
            );
            oepbs_content_parts["guide"] ~=
              format(q"¶      <reference type="%s#%s" href="%s#%s" />
  ¶",
              obj.segment_anchor_tag,
              obj.obj_cite_number,
              obj.segment_anchor_tag,
              obj.obj_cite_number,
            );
          }
        }
      }
    }
    /+ epub specific documents +/
    auto mimetypes = epub3_mimetypes;
    auto meta_inf_container_xml = epub3_container_xml;
    auto oebps_toc_ncx = epub2_oebps_toc_ncx(doc_abstraction, doc_matters);
    auto oebps_toc_nav_xhtml = epub3_oebps_toc_nav_xhtml(doc_abstraction, doc_matters);
    auto oebps_content_opf = epub3_oebps_content(doc_abstraction, doc_matters, oepbs_content_parts);
    epub3_write_output_files(
      doc_matters,
      doc_epub3,
      doc_epub3_endnotes,
      mimetypes,
      meta_inf_container_xml,
      oebps_toc_nav_xhtml,
      oebps_toc_ncx,
      oebps_content_opf,
      doc_parts_,
    );
  }
  void epub3_write_output_files(M,D,E,Mt,Mic,Otnx,Otn,Oc)(
    M    doc_matters,
    D    doc_epub3,
    E    doc_epub3_endnotes,
    Mt   mimetypes,
    Mic  meta_inf_container_xml,
    Otnx oebps_toc_nav_xhtml,
    Otn  oebps_toc_ncx,
    Oc   oebps_content_opf,
    string[] doc_parts_,
  ) {
    debug(asserts) {
      static assert(is(typeof(doc_epub3)              == string[][string]));
      static assert(is(typeof(mimetypes)              == string));
      static assert(is(typeof(meta_inf_container_xml) == string));
      static assert(is(typeof(oebps_toc_nav_xhtml)    == string));
      static assert(is(typeof(oebps_toc_ncx)          == string));
      static assert(is(typeof(oebps_content_opf)      == string));
    }
    auto src_path_info = doc_matters.src_path_info;
    string lng = doc_matters.language;
    auto pth_epub3 = SiSUpathsEPUB!()(src_path_info, lng);
    auto xhtml_format = outputXHTMLs();
    /+ zip file +/
    auto fn_epub = pth_epub3.epub_file(doc_matters.source_filename);
    auto zip = new ZipArchive(); // ZipArchive zip = new ZipArchive();
    /+ zip archive member files +/
    try {
      if (!exists(pth_epub3.base)) {
        pth_epub3.base.mkdirRecurse;
      }
      debug(epub_output) {
        if (!exists(pth_epub3.dbg_doc_meta_inf(doc_matters.source_filename))) {
          pth_epub3.dbg_doc_meta_inf(doc_matters.source_filename).mkdirRecurse;
        }
        if (!exists(pth_epub3.dbg_doc_oebps_css(doc_matters.source_filename))) {
          pth_epub3.dbg_doc_oebps_css(doc_matters.source_filename).mkdirRecurse;
        }
        if (!exists(pth_epub3.dbg_doc_oebps_image(doc_matters.source_filename))) {
          pth_epub3.dbg_doc_oebps_image(doc_matters.source_filename).mkdirRecurse;
        }
      }
      { /+ OEBPS/[segments].xhtml (the document contents) +/
        foreach (seg_filename; doc_matters.segnames_lv_0_to_4) {
          string fn = pth_epub3.fn_oebps_content_xhtml(doc_matters.source_filename, seg_filename);
          auto zip_arc_member_file = new ArchiveMember();
          zip_arc_member_file.name = fn;
          auto zip_data = new OutBuffer();
          debug(epub_output) {
            string fn_dbg = pth_epub3.dbg_fn_oebps_content_xhtml(doc_matters.source_filename, seg_filename);
            auto f = File(fn_dbg, "w");
          }
          foreach (docseg; doc_epub3[seg_filename]) {
            debug(epub_output) { f.writeln(docseg); }
            zip_data.write(docseg.dup);
          }
          foreach (docseg; doc_epub3_endnotes[seg_filename]) {
            debug(epub_output) { f.writeln(docseg); }
            zip_data.write(docseg.dup);
          }
          debug(epub_output) { f.writeln(xhtml_format.tail); }
          zip_data.write(xhtml_format.tail.dup);
          zip_arc_member_file.expandedData = zip_data.toBytes();
          zip.addMember(zip_arc_member_file);
          /+ create the zip file +/
          createZipFile!()(fn_epub, zip.build());
        }
      }
      string fn;
      debug(epub_output) { string fn_dbg; }
      File f;
      { /+ mimetypes (identify zip file type) +/
        debug(epub_output) {
          fn_dbg = pth_epub3.dbg_fn_mimetypes(doc_matters.source_filename);
          File(fn_dbg, "w").writeln(mimetypes);
        }
        fn = pth_epub3.fn_mimetypes(doc_matters.source_filename);
        auto zip_arc_member_file = new ArchiveMember();
        zip_arc_member_file.name = fn;
        auto zip_data = new OutBuffer();
        zip_data.write(mimetypes.dup);
        zip_arc_member_file.expandedData = zip_data.toBytes();
        zip.addMember(zip_arc_member_file);
        createZipFile!()(fn_epub, zip.build());
      }
      { /+  META-INF/container.xml (identify doc root) +/
        debug(epub_output) {
          fn_dbg = pth_epub3.dbg_fn_dmi_container_xml(doc_matters.source_filename);
          File(fn_dbg, "w").writeln(meta_inf_container_xml);
        }
        fn = pth_epub3.fn_dmi_container_xml(doc_matters.source_filename);
        auto zip_arc_member_file = new ArchiveMember();
        zip_arc_member_file.name = fn;
        auto zip_data = new OutBuffer();
        zip_data.write(meta_inf_container_xml.dup);
        zip_arc_member_file.expandedData = zip_data.toBytes();
        zip.addMember(zip_arc_member_file);
        createZipFile!()(fn_epub, zip.build());
      }
      { /+ OEBPS/toc_nav.xhtml (navigation toc epub3) +/
        debug(epub_output) {
          fn_dbg = pth_epub3.dbg_fn_oebps_toc_nav_xhtml(doc_matters.source_filename);
          File(fn_dbg, "w").writeln(oebps_toc_nav_xhtml);
        }
        fn = pth_epub3.fn_oebps_toc_nav_xhtml(doc_matters.source_filename);
        auto zip_arc_member_file = new ArchiveMember();
        zip_arc_member_file.name = fn;
        auto zip_data = new OutBuffer();
        zip_data.write(oebps_toc_nav_xhtml.dup);
        zip_arc_member_file.expandedData = zip_data.toBytes();
        zip.addMember(zip_arc_member_file);
        createZipFile!()(fn_epub, zip.build());
      }
      { /+ OEBPS/toc.ncx (navigation toc epub2) +/
        debug(epub_output) {
          fn_dbg = pth_epub3.dbg_fn_oebps_toc_ncx(doc_matters.source_filename);
          File(fn_dbg, "w").writeln(oebps_toc_ncx);
        }
        fn = pth_epub3.fn_oebps_toc_ncx(doc_matters.source_filename);
        auto zip_arc_member_file = new ArchiveMember();
        zip_arc_member_file.name = fn;
        auto zip_data = new OutBuffer();
        zip_data.write(oebps_toc_ncx.dup);
        zip_arc_member_file.expandedData = zip_data.toBytes();
        zip.addMember(zip_arc_member_file);
        createZipFile!()(fn_epub, zip.build());
      }
      { /+ OEBPS/content.opf (doc manifest) +/
        debug(epub_output) {
          fn_dbg = pth_epub3.dbg_fn_oebps_content_opf(doc_matters.source_filename);
          File(fn_dbg, "w").writeln(oebps_content_opf);
        }
        fn = pth_epub3.fn_oebps_content_opf(doc_matters.source_filename);
        auto zip_arc_member_file = new ArchiveMember();
        zip_arc_member_file.name = fn;
        auto zip_data = new OutBuffer();
        zip_data.write(oebps_content_opf.dup);
        zip_arc_member_file.expandedData = zip_data.toBytes();
        zip.addMember(zip_arc_member_file);
        createZipFile!()(fn_epub, zip.build());
      }
      { /+ OEBPS/_sisu/image (images) +/
        foreach (image; doc_matters.image_list) {
          debug(epub_output) {
            if (exists(doc_matters.src_path_info.image_root ~ "/" ~ image)) {
              (doc_matters.src_path_info.image_root ~ "/" ~ image)
              .copy((pth_epub3.dbg_doc_oebps_image(doc_matters.source_filename)) ~ "/" ~ image);
            }
          }
        }
        foreach (image; doc_matters.image_list) {
          debug(epub_output) {
            debug(epub_images) {
              writeln(
                doc_matters.src_path_info.image_root, image, " -> ",
                pth_epub3.dbg_doc_oebps_image(doc_matters.source_filename), "/", image
              );
            }
          }
          auto fn_src = doc_matters.src_path_info.image_root ~ image;
          auto fn_out =  pth_epub3.doc_oebps_image(doc_matters.source_filename).to!string ~ "/" ~ image;
          if (exists(fn_src)) {
            {
              auto zip_arc_member_file = new ArchiveMember();
              zip_arc_member_file.name = fn_out;
              auto zip_data = new OutBuffer();
              zip_data.write(cast(char[]) ((fn_src).read));
              zip_arc_member_file.expandedData = zip_data.toBytes();
              zip.addMember(zip_arc_member_file);
              createZipFile!()(fn_epub, zip.build());
            }
          }
        }
      }
      { /+ OEBPS/epub.css +/
        auto css = SiSUcss();
        debug(epub_output) {
          fn_dbg = pth_epub3.dbg_fn_oebps_css(doc_matters.source_filename);
          File(fn_dbg, "w").writeln(css.epub_css);
        }
        fn = pth_epub3.fn_oebps_css(doc_matters.source_filename);
        auto zip_arc_member_file = new ArchiveMember();
        zip_arc_member_file.name = fn;
        auto zip_data = new OutBuffer();
        zip_data.write(css.epub_css.dup);
        zip_arc_member_file.expandedData = zip_data.toBytes();
        zip.addMember(zip_arc_member_file);
        createZipFile!()(fn_epub, zip.build());
      }
    }
    catch (ErrnoException ex) {
      // Handle error
    }
    writeln(" ", doc_matters.environment["pwd"],  "/", fn_epub);
    debug(epub_archive) {
      if (exists(fn_epub)) {
        try {
          auto zipped = new ZipArchive((fn_epub).read);
          foreach (filename, member; zipped.directory) {
            auto data = zipped.expand(member);
            writeln(filename, " length ", data.length);
          }
        }
        catch (ZipException ex) {
          // Handle errors
        }
      }
    }
  }
  
}