path: root/flake.nix

{
  description = "a sisu like parser & document generator";
  inputs.nixpkgs.url = "https://channels.nixos.org/nixpkgs-unstable/nixexprs.tar.zst";
  outputs = {
    self,
    nixpkgs,
    ...
  }@inputs: let
    pname = "spine";
    version = "0.25.1";
    supportedSystems = ["x86_64-linux"]; # [ "x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin" ];
    forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
    nixpkgsFor = forAllSystems (system: import nixpkgs {inherit system;}); # nixpkgs instantiated for supported system types
    localOverlay = (final: prev: {
      ldc = prev.callPackage ./nix-overlays/ldc {  };                           # -> ok 1.43.0
      # dmd overlay: revert to GCC14; (current) GCC 15 introduced nullptr in its headers, and DMD's ImportC parser needs update to handle it, monitor and update:
      dmd = prev.callPackage ./nix-overlays/dmd { stdenv = prev.gcc14Stdenv; }; # -> ok 2.112.1
      dub = prev.callPackage ./nix-overlays/dub {  };                           # -> ? 1.41.0
      dtools = prev.callPackage ./nix-overlays/dtools {  };                     # -> ok 2.112.1
      #gdc = prev.callPackage ./nix-overlays/gdc {  };
    });
    pkgsForSystem = system: import nixpkgs {
      overlays = [
        localOverlay
      ];
      inherit system;
    };
    mkSpine = { pkgs, compilerPkg, compilerBin, buildType }: pkgs.stdenv.mkDerivation {
      inherit pname version;
      meta.mainProgram = "spine";
      executable = true; # not used
      src = self;
      buildInputs = [ pkgs.sqlite pkgs.zstd.out ];
      nativeBuildInputs = [ pkgs.dub compilerPkg pkgs.gnumake ];
      preBuild = ''
        export HOME=$TMPDIR
      '';
      buildPhase = ''
        runHook preBuild
        buildCMD="dub run --cache=local --compiler=$(type -P ${compilerBin}) --build=${buildType} --combined --skip-registry=all"
        echo $buildCMD
        $buildCMD
        echo $buildCMD
        runHook postBuild
      '';
      checkPhase = ''
        runHook preCheck
        dub test --combined --skip-registry=all
        runHook postCheck
      '';
      installPhase = ''
        runHook preInstall
        mkdir -p $out/bin
        install -m755 ./bin/spine $out/bin/spine
        runHook postInstall
      '';
      postInstall = ''
        echo "❯❯ ./result/bin/spine -v --source --pod --text --epub --html --html-link-pdf --html-link-curate --html-link-markup --curate --output=./OUTPUT_TEST ../sisu-spine-samples/markup/pod-samples/pod/*";
        echo `ls -la $out/bin/spine`
        echo "❯❯ spine-v${version} (rev: ${self.shortRev or "unknown"})"
        $out/bin/spine -v
      '';
    };
    shellHook = ''
      #export Date=`date "+%Y%m%d"`
      ## set local values in .envrc-local (or here if you must)
      echo '❯❯ nix build';
      ## ImPure Nix environment
      SpineGitVer=`git describe | sed "s/^[a-z_-]\+\([0-9.]\+\)/\1/" | sed "s/\([^-]*-g\)/r\1/" | sed "s/-/./g"` && \
      SpineGitBranch=`git branch --show-current` && \
      echo "❯❯ spine-v${version} - ($SpineGitBranch: $SpineGitVer)"
      ## Pure Nix environment - version info from flake inputs
      #echo "❯❯ spine-v${version} (rev: ${self.shortRev or "unknown"})"
      echo '❯❯ $SpineBIN -v --source --pod --text --epub --html --html-link-pdf --html-link-curate --html-link-markup --curate --output=$SpineOUT  $SpinePOD/*';
      echo "❯❯ $SpineBIN -v --source --pod --text --epub --html --html-link-pdf --html-link-curate --html-link-markup --curate --output=$SpineOUT  $SpinePOD/*";
      echo '❯❯ nix flake update && nix flake check && nix flake show';
    '';
    mkDevShell = { pkgs, name, compiler, extraPackages ? [] }: pkgs.mkShell {
      inherit name shellHook;
      packages = [
        pkgs.direnv
        pkgs.nix-direnv
        compiler
        pkgs.dub
        pkgs.dtools
        pkgs.gnumake
        pkgs.sqlite
        pkgs.zstd
        pkgs.gnugrep
        pkgs.gnused
        pkgs.ripgrep
      ] ++ extraPackages;
    };
  in {
    packages = forAllSystems (system: let
      pkgs-ovl = pkgsForSystem system;
      pkgs-nix = nixpkgsFor.${system};
    in {
      default = self.packages.${system}.spine-nixpkgs-ldc;
      spine-nixpkgs-dmd = mkSpine {
        pkgs = pkgs-nix;
        # nixpkgs dmd: revert to GCC14 (same nullptr/ImportC fix as overlay dmd)
        compilerPkg = pkgs-nix.dmd.override { stdenv = pkgs-nix.gcc14Stdenv; };
        #compilerPkg = pkgs-nix.dmd;
        compilerBin = "dmd";
        buildType = "dmd";
      };
      spine-nixpkgs-ldc = mkSpine {
        pkgs = pkgs-nix;
        compilerPkg = pkgs-nix.ldc;
        compilerBin = "ldmd2";
        buildType = "ldmd2";
      };
      spine-overlay-dmd = mkSpine {
        pkgs = pkgs-ovl;
        compilerPkg = pkgs-ovl.dmd;
        compilerBin = "dmd";
        buildType = "dmd";
      };
      spine-overlay-ldc = mkSpine {
        pkgs = pkgs-ovl;
        compilerPkg = pkgs-ovl.ldc;
        compilerBin = "ldmd2";
        buildType = "ldmd2";
      };
      #spine-overlay-gdc = mkSpine {
      #  pkgs = pkgs-ovl;
      #  compilerPkg = pkgs-ovl.gdc;
      #  compilerBin = "gdc";
      #  buildType = "gdc";
      #};
    });
    apps = forAllSystems (system: {
      default = {
        type = "app";
        program = "${self.packages.${system}.default}/bin/spine";
      };
    });
    devShells = forAllSystems (system: let
      pkgs-ovl = pkgsForSystem system;
      pkgs-nix = nixpkgsFor.${system};
    in {
      default = self.devShells.${system}.dsh-overlay;
      #default = import ./shell.nix {pkgs = pkgs-nix; flake = self;};
      dsh-overlay = mkDevShell {
        pkgs = pkgs-ovl;
        # "spine-0.25.1 base dev shell, ldc-1.43.0, dub-1.41.0 - dtools-2.112.1";
        name = "spine-${version} dev shell (overlay ldc)";
        compiler = pkgs-ovl.ldc;
      };
      dsh-nixpkgs-dmd = mkDevShell {
        pkgs = pkgs-nix;
        name = "spine-${version} dev shell (nixpkgs dmd)";
        # nixpkgs dmd: revert to GCC14 (same nullptr/ImportC fix as overlay dmd)
        compiler = pkgs-nix.dmd.override { stdenv = pkgs-nix.gcc14Stdenv; };
        #compiler = pkgs-nix.dmd;
      };
      dsh-nixpkgs-ldc = mkDevShell {
        pkgs = pkgs-nix;
        name = "spine-${version} dev shell (nixpkgs ldc)";
        compiler = pkgs-nix.ldc;
      };
      dsh-overlay-dmd = mkDevShell {
        pkgs = pkgs-ovl;
        # "spine-0.25.1 base dev shell, dmd-2.112.1, dub-1.41.0 - dtools-2.112.1";
        name = "spine-${version} dev shell (overlay dmd)";
        compiler = pkgs-ovl.dmd;
      };
      dsh-overlay-ldc = mkDevShell {
        pkgs = pkgs-ovl;
        # "spine-0.25.1 base dev shell, ldc-1.43.0, dub-1.41.0 - dtools-2.112.1";
        name = "spine-${version} dev shell (overlay ldc)";
        compiler = pkgs-ovl.ldc;
      };
      dsh-epub = mkDevShell {
        pkgs = pkgs-nix;
        name = "spine-${version} dev shell for epub output";
        compiler = pkgs-nix.ldc;
        extraPackages = with pkgs-nix; [
          libxml2
          html-tidy
          xmlstarlet
          epubcheck
          ebook_tools
          epr
          sigil
          calibre #(suite includes: ebook-viewer)
          koreader
          foliate
        ];
      };
      dsh-html = mkDevShell {
        pkgs = pkgs-nix;
        name = "spine-${version} dev shell for html output";
        compiler = pkgs-nix.ldc;
        extraPackages = with pkgs-nix; [
          # ❯❯ text-mode web browsers
          elinks
          links2
          lynx
          w3m
          # ❯❯ light graphical
          #dillo
        ];
      };
      dsh-odf = mkDevShell {
        pkgs = pkgs-nix;
        name = "spine-${version} dev shell for epub output";
        compiler = pkgs-nix.ldc;
        extraPackages = with pkgs-nix; [
          jing
        ];
      };
      dsh-typst-pdf = mkDevShell {
        pkgs = pkgs-nix;
        name = "spine-${version} dev shell for latex & pdf output";
        compiler = pkgs-nix.ldc;
        extraPackages = with pkgs-nix; [
          typst
          #typstyle
          #typst-live
          #typstwriter
        ];
      };
      dsh-latex-pdf = mkDevShell {
        pkgs = pkgs-nix;
        name = "spine-${version} dev shell for latex & pdf output";
        compiler = pkgs-nix.ldc;
        extraPackages = with pkgs-nix; [
          source-sans-pro
          source-serif-pro
          source-code-pro
          texliveFull
        ];
      };
      dsh-sqlite = mkDevShell {
        pkgs = pkgs-nix;
        name = "spine-${version} dev shell for sqlite3 output";
        compiler = pkgs-nix.ldc;
        extraPackages = with pkgs-nix; [
          #sqlite
          sqlite-interactive
          litecli
          visidata
          sqlitebrowser
          letos
          dbeaver-bin
        ];
      };
      dsh-translations = mkDevShell {
        pkgs = pkgs-nix;
        name = "spine-${version} dev shell for internationalization, po4a";
        compiler = pkgs-nix.ldc;
        extraPackages = with pkgs-nix; [
          po4a
          gettext
        ];
      };
      dsh-production = mkDevShell {
        pkgs = pkgs-nix;
        name = "spine-${version} dev shell: production run and its checks";
        compiler = pkgs-nix.ldc;
        extraPackages = with pkgs-nix; [
          # the suite shells out to these two; without them run-tests.sh
          # re-execs itself into a nix shell that has them
          sqlite-interactive   # readline cli; base sqlite has none
          epubcheck
          unzip                # containers: every one spine writes is a zip
          # xml and html by eye and by check
          libxml2              # xmllint
          xmlstarlet           # xml sel -t -v
          html-tidy            # the scroll html, which epubcheck never sees
          # pdf
          poppler-utils        # pdfinfo, pdftotext
          typst
          #texliveFull          # NOT texlive.combined.scheme-full: deprecated,
          file                 # what a file is
        ];
      };
      dsh-production-post = mkDevShell {
        pkgs = pkgs-nix;
        name = "spine-${version} dev shell: production run and its checks";
        compiler = pkgs-nix.ldc;
        extraPackages = with pkgs-nix; [
          # the suite shells out to these two; without them run-tests.sh
          # re-execs itself into a nix shell that has them
          sqlite-interactive   # readline cli; base sqlite has none
          #datasette            # serves an .ocda.db as a browsable, queryable web page with a json api, one command, no configuration
          letos
          epubcheck
          diffoscope           # diffs two epubs, two odts or two pdfs by content rather (than as bytes) (useful when output moves and cmp only says "differ")
          unzip                # containers: every one spine writes is a zip
          # xml and html by eye and by check
          libxml2              # xmllint
          xmlstarlet           # xml sel -t -v
          html-tidy            # the scroll html, which epubcheck never sees
          xmlstarlet
          ebook_tools
          #jing
          # pdf
          poppler-utils        # pdfinfo, pdftotext
          typst
          #texliveFull          # NOT texlive.combined.scheme-full: deprecated,
          file                 # what a file is
          coreutils            # sha256sum and numfmt guaranteed, for checking a digests.txt line by hand
          po4a
          gettext
        ];
      };
    });
  };
}